wannier.F90

Go to the documentation of this file.

!! Copyright (C) A Buccheri, J Reimann. 2026
!!
!! This Source Code Form is subject to the terms of the Mozilla Public
!! License, v. 2.0. If a copy of the MPL was not distributed with this
!! file, You can obtain one at https://mozilla.org/MPL/2.0/.
 
#include "global.h"
 
module wannier_oct_m
  use, intrinsic :: iso_fortran_env
 
  use debug_oct_m
  use global_oct_m
  use electron_space_oct_m
  use io_oct_m
  use ions_oct_m
  use kpoints_oct_m
  use mesh_oct_m
  use messages_oct_m
  use mpi_oct_m
  use multicomm_oct_m
  use namespace_oct_m
  use output_low_oct_m
  use parser_oct_m
  use profiling_oct_m
  use restart_oct_m
  use states_elec_oct_m
  use states_elec_restart_oct_m
  use types_oct_m
  use unit_oct_m
  use unit_system_oct_m
  use wannier_calc_oct_m, &
    only: &
    wannier_calc_read_centers, &
    wannier_calc_read_u_matrices, &
    wannier_calc_write_u_matrices, &
    wannier_calc_write_centers
  use wannier_opts_oct_m
  use wfs_elec_oct_m, only: wfs_elec_t
  use ylm_wannier_oct_m
 
#ifdef HAVE_WANNIER90
  use w90_library
  use wannier90lib_interface_oct_m, only: wannier90lib_init_w90main
#endif
 
  implicit none
  private
 
  public :: wannier_t
  type :: wannier_t
    type(wannier_opts_t)         :: options
    complex(real64), allocatable :: u_matrix(:,:,:)
    complex(real64), allocatable :: u_dis_matrix(:,:,:)
    real(real64),    allocatable :: centers(:,:)
#ifdef HAVE_WANNIER90
    type(lib_common_type) :: w90main
#endif
 
  contains
    procedure :: init_from_input => wannier_init_from_input
    procedure :: init_parallelization => wannier_init_parallelization
    procedure :: init_data_from_file => wannier_init_data_from_file
    procedure :: restart_write_data => wannier_restart_write_data
    procedure :: restart_read_data => wannier_restart_read_data
    procedure :: write_iter => wannier_write_iter
    final :: wannier_finalize
  end type wannier_t
 
contains
 
  subroutine wannier_init_from_input(this, namespace, kpoints)
    class(wannier_t), intent(inout) :: this
    type(namespace_t), intent(in) :: namespace
    type(kpoints_t), intent(in) :: kpoints
 
    push_sub(wannier_init_from_input)
 
    ! Parse all Wannier related options
    call this%options%parse_oct(namespace)
    if (this%options%td_method /= td_wannier_method_none) then
      call this%options%parse_win()
    end if
 
    safe_allocate(this%u_matrix(1:this%options%num_wann, 1:this%options%num_wann, 1:product(kpoints%nik_axis)))
    safe_allocate(this%u_dis_matrix(1:this%options%num_bands, 1:this%options%num_wann, 1:product(kpoints%nik_axis)))
    safe_allocate(this%centers(1:3, 1:this%options%num_wann))
    this%u_matrix = m_zero
    this%u_dis_matrix = m_zero
    this%centers = m_zero
 
    pop_sub(wannier_init_from_input)
  end subroutine wannier_init_from_input
 
  subroutine wannier_init_parallelization(this, namespace, st, ions, kpoints)
    class(wannier_t), intent(inout)   :: this
    type(namespace_t), intent(in)     :: namespace
    type(states_elec_t), intent(in)   :: st
    type(ions_t), intent(in)          :: ions
    type(kpoints_t), intent(in)       :: kpoints
 
#ifdef HAVE_WANNIER90
    integer :: ierr
#endif
 
    push_sub(wannier_init_parallelization)
#ifdef HAVE_WANNIER90
    if (this%options%td_method /= td_wannier_method_none) then
      call wannier90lib_init_w90main(namespace, ions, kpoints, st, &
        this%options, this%w90main, stdout, stderr, ierr)
      if (ierr /= 0) then
        write(message(1),'(a,i0)') 'Error initializing wannier90 library object: ', ierr
        call messages_fatal(1)
      end if
    end if
#endif
 
    pop_sub(wannier_init_parallelization)
 
  end subroutine wannier_init_parallelization
 
  subroutine wannier_init_data_from_file(this, kpoints, space)
    class(wannier_t),       intent(inout) :: this
    type(kpoints_t),        intent(in)    :: kpoints
    type(electron_space_t), intent(in)    :: space
 
    push_sub(wannier_init_data_from_file)
 
    if (this%options%td_method /= td_wannier_method_none) then
      if (space%dim /= 3) then     ! see issue #1466
        call messages_not_implemented("TD wannier: only 3D is supported")
      end if
      call wannier_calc_read_centers(this%options, this%centers)
      call wannier_calc_read_u_matrices(this%options, kpoints, this%u_matrix, this%u_dis_matrix)
    end if
#ifdef HAVE_WANNIER90
    call w90_set_u_matrix(this%w90main, this%u_matrix)
    call w90_set_u_opt(this%w90main, this%u_dis_matrix)
    this%w90main%wannier_data%centres = this%centers
#endif
 
    pop_sub(wannier_init_data_from_file)
  end subroutine wannier_init_data_from_file
 
  subroutine wannier_restart_write_data(this, namespace, mc, gr)
    class(wannier_t), intent(inout) :: this
    type(namespace_t), intent(in)   :: namespace
    type(multicomm_t), intent(in)   :: mc
    class(mesh_t), intent(in)       :: gr
 
    type(restart_t) :: restart
    integer :: ierr
 
    push_sub(wannier_restart_write_data)
 
    call restart%init(namespace, restart_td, restart_type_dump, mc, ierr, mesh=gr)
    if (ierr /= 0) then
      message(1) = 'Unable to initialize TD restart for Wannier write.'
      call messages_fatal(1)
    end if
 
    call restart%write_binary('wannier_u_matrix', size(this%u_matrix), this%u_matrix, ierr)
    if (ierr /= 0) then
      message(1) = 'Unable to write Wannier restart data (u_matrix).'
      call messages_fatal(1)
    end if
 
    call restart%write_binary('wannier_u_dis_matrix', size(this%u_dis_matrix), this%u_dis_matrix, ierr)
    if (ierr /= 0) then
      message(1) = 'Unable to write Wannier restart data (u_dis_matrix).'
      call messages_fatal(1)
    end if
 
    call restart%write_binary('wannier_centers', size(this%centers), this%centers, ierr)
    if (ierr /= 0) then
      message(1) = 'Unable to write Wannier restart data (centers).'
      call messages_fatal(1)
    end if
 
    call restart%end()
 
    pop_sub(wannier_restart_write_data)
  end subroutine wannier_restart_write_data
 
  subroutine wannier_restart_read_data(this, namespace, mc, gr)
    class(wannier_t), intent(inout) :: this
    type(namespace_t), intent(in)   :: namespace
    type(multicomm_t), intent(in)   :: mc
    class(mesh_t), intent(in)       :: gr
 
    type(restart_t) :: restart
    integer :: ierr
 
    push_sub(wannier_restart_read_data)
 
    call restart%init(namespace, restart_td, restart_type_load, mc, ierr, mesh=gr)
    if (ierr /= 0) then
      message(1) = 'Unable to initialize TD restart for Wannier read.'
      call messages_fatal(1)
    end if
 
    call restart%read_binary('wannier_u_matrix', size(this%u_matrix), this%u_matrix, ierr)
    if (ierr /= 0) then
      message(1) = 'Unable to read Wannier restart data (u_matrix).'
      call messages_fatal(1)
    end if
 
    call restart%read_binary('wannier_u_dis_matrix', size(this%u_dis_matrix), this%u_dis_matrix, ierr)
    if (ierr /= 0) then
      message(1) = 'Unable to read Wannier restart data (u_dis_matrix).'
      call messages_fatal(1)
    end if
 
    call restart%read_binary('wannier_centers', size(this%centers), this%centers, ierr)
    if (ierr /= 0) then
      message(1) = 'Unable to read Wannier restart data (centers).'
      call messages_fatal(1)
    end if
 
#ifdef HAVE_WANNIER90
    call w90_set_u_matrix(this%w90main, this%u_matrix)
    call w90_set_u_opt(this%w90main, this%u_dis_matrix)
    this%w90main%wannier_data%centres = this%centers
#endif
 
    call restart%end()
 
    pop_sub(wannier_restart_read_data)
  end subroutine wannier_restart_read_data
 
  subroutine wannier_write_iter(this, namespace, outp, iter, ions, kpoints)
    class(wannier_t), intent(in) :: this
    type(namespace_t), intent(in)   :: namespace
    type(output_t), intent(inout)   :: outp
    integer, intent(in)             :: iter
    class(ions_t), intent(in)       :: ions
    type(kpoints_t), intent(in)     :: kpoints
 
    character(len=MAX_PATH_LEN) :: dir, raw_dir
 
    push_sub(wannier_write_iter)
 
    ! Only write wannier90 output every n iterations, as specified in input
    if (mod(iter, this%options%td_output_interval) == 0) then
      write(dir, '(a,a,i7.7)') trim(outp%iter_dir),"td.", iter  ! name of directory
      raw_dir = io_workpath(trim(dir), namespace)
 
      call io_mkdir(trim(dir), namespace, parents=.true.)
 
      if (this%options%td_method /= td_wannier_method_none) then
        call wannier_calc_write_u_matrices(trim(raw_dir), trim(this%options%prefix), kpoints, this%u_matrix, this%u_dis_matrix)
        call wannier_calc_write_centers(trim(raw_dir), trim(this%options%prefix), this%centers, ions)
      end if
    end if
 
    pop_sub(wannier_write_iter)
  end subroutine wannier_write_iter
 
  subroutine wannier_finalize(wan)
    type(wannier_t), intent(inout) :: wan
 
    push_sub(wannier_finalize)
 
    safe_deallocate_a(wan%u_matrix)
    safe_deallocate_a(wan%u_dis_matrix)
    safe_deallocate_a(wan%centers)
#ifdef HAVE_WANNIER90
    ! Attributes of `lib_common_type` are just pointers to memory we own, so no additional finalisation required
#endif
 
    pop_sub(wannier_finalize)
  end subroutine wannier_finalize
 
end module wannier_oct_m