gravity.F90

Go to the documentation of this file.

!! Copyright (C) 2020 M. Oliveira, Heiko Appel
!!
!! This program is free software; you can redistribute it and/or modify
!! it under the terms of the GNU General Public License as published by
!! the Free Software Foundation; either version 2, or (at your option)
!! any later version.
!!
!! This program is distributed in the hope that it will be useful,
!! but WITHOUT ANY WARRANTY; without even the implied warranty of
!! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!! GNU General Public License for more details.
!!
!! You should have received a copy of the GNU General Public License
!! along with this program; if not, write to the Free Software
!! Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
!! 02110-1301, USA.
!!
 
#include "global.h"
 
module gravity_oct_m
  use debug_oct_m
  use force_interaction_oct_m
  use global_oct_m
  use interaction_oct_m
  use interaction_partner_oct_m
  use, intrinsic :: iso_fortran_env
  use messages_oct_m
  use namespace_oct_m
  use profiling_oct_m
  use quantity_oct_m
 
  implicit none
 
  private
  public ::                &
    gravity_t
 
  type, extends(force_interaction_t) :: gravity_t
    private
    real(real64), pointer :: system_mass(:) => null() 
    real(real64), pointer :: system_pos(:,:) => null() 
 
    integer, public :: partner_np = 0
    real(real64), allocatable, public :: partner_mass(:)
    real(real64), allocatable, public :: partner_pos(:,:)
 
  contains
    procedure :: init => gravity_init
    procedure :: calculate => gravity_calculate
    procedure :: calculate_energy => gravity_calculate_energy
    final :: gravity_finalize
  end type gravity_t
 
  interface gravity_t
    module procedure gravity_constructor
  end interface gravity_t
 
contains
  ! ---------------------------------------------------------
  function gravity_constructor(partner) result(this)
    class(interaction_partner_t), target, intent(inout) :: partner
    class(gravity_t),                     pointer       :: this
 
    push_sub(gravity_constructor)
 
    allocate(this)
 
    this%label = "gravity"
 
    this%partner => partner
 
    ! Gravity interaction needs two quantities from each system: the position and the mass
    ! From the sytem:
    this%system_quantities = [position, mass]
 
    ! From the partner:
    this%couplings_from_partner = [position, mass]
 
    pop_sub(gravity_constructor)
  end function gravity_constructor
 
  ! ---------------------------------------------------------
  subroutine gravity_init(this, dim, system_np, system_mass, system_pos)
    class(gravity_t),                     intent(inout) :: this
    integer,                              intent(in)    :: dim
    integer,                              intent(in)    :: system_np
    real(real64),                 target, intent(in)    :: system_mass(:)
    real(real64),                 target, intent(in)    :: system_pos(:,:)
 
    push_sub(gravity_init)
 
    this%dim = dim
    this%system_np = system_np
    safe_allocate(this%force(1:dim, 1:system_np))
    this%force = m_zero
    this%system_mass => system_mass
    this%system_pos => system_pos
 
    pop_sub(gravity_init)
  end subroutine gravity_init
 
  ! ---------------------------------------------------------
  subroutine gravity_calculate(this)
    class(gravity_t),             intent(inout) :: this
 
    integer :: ip, jp
    real(real64), parameter :: GG = 6.67430e-11_real64 ! In S.I. units!
    real(real64) :: dist3
    push_sub(gravity_calculate)
 
    assert(allocated(this%partner_mass))
    assert(allocated(this%partner_pos))
 
    do ip = 1, this%system_np
      do jp = 1, this%partner_np
        if (this%intra_interaction .and. ip == jp ) cycle
 
        dist3 = sum((this%partner_pos(1:this%dim, jp) - this%system_pos(1:this%dim, ip))**2)**(m_three/m_two)
 
        this%force(1:this%dim, ip) = (this%partner_pos(1:this%dim, jp) - this%system_pos(1:this%dim, ip)) &
          / (dist3 + m_epsilon) * (gg * this%system_mass(ip) * this%partner_mass(jp))
      end do
    end do
 
    pop_sub(gravity_calculate)
  end subroutine gravity_calculate
 
  ! ---------------------------------------------------------
  subroutine gravity_calculate_energy(this)
    class(gravity_t),             intent(inout) :: this
 
    integer :: ip, jp
    real(real64), parameter :: gg = 6.67430e-11_real64 ! In S.I. units!
    real(real64) :: dist
 
    push_sub(gravity_calculate_energy)
 
    assert(allocated(this%partner_mass))
    assert(allocated(this%partner_pos))
 
    this%energy = m_zero
    do ip = 1, this%system_np
      do jp = 1, this%partner_np
        if (this%intra_interaction .and. ip == jp ) cycle
 
        dist = sqrt(sum((this%partner_pos(1:this%dim, jp) - this%system_pos(1:this%dim, ip))**2))
 
        this%energy = this%energy - m_half / (dist + m_epsilon) * (gg * this%system_mass(ip) * this%partner_mass(jp))
      end do
    end do
 
    pop_sub(gravity_calculate_energy)
  end subroutine gravity_calculate_energy
 
 
  ! ---------------------------------------------------------
  subroutine gravity_finalize(this)
    type(gravity_t), intent(inout) :: this
 
    push_sub(gravity_finalize)
 
    this%force = m_zero
    nullify(this%system_mass)
    nullify(this%system_pos)
    safe_deallocate_a(this%partner_pos)
    safe_deallocate_a(this%partner_mass)
    safe_deallocate_a(this%force)
 
    call interaction_end(this)
 
    pop_sub(gravity_finalize)
  end subroutine gravity_finalize
 
end module gravity_oct_m
 
!! Local Variables:
!! mode: f90
!! coding: utf-8
!! End: