fourier_space.F90

Go to the documentation of this file.

!! Copyright (C) 2002-2006 M. Marques, A. Castro, A. Rubio, G. Bertsch.
!! Copyright (C) 2026 A. Buccheri.
!!
!! This program is free software; you can redistribute it and/or modify
!! it under the terms of the GNU General Public License as published by
!! the Free Software Foundation; either version 2, or (at your option)
!! any later version.
!!
!! This program is distributed in the hope that it will be useful,
!! but WITHOUT ANY WARRANTY; without even the implied warranty of
!! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!! GNU General Public License for more details.
!!
!! You should have received a copy of the GNU General Public License
!! along with this program; if not, write to the Free Software
!! Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
!! 02110-1301, USA.
!!
 
#include "global.h"
 
module fourier_space_oct_m
  use accel_oct_m
  use cube_oct_m
  use cube_function_oct_m
  use debug_oct_m
  use global_oct_m
  use, intrinsic :: iso_fortran_env
  use math_oct_m
  use messages_oct_m
  use namespace_oct_m
  use fft_oct_m
#ifdef HAVE_OPENMP
  use omp_lib
#endif
#ifdef HAVE_PFFT
  use pfft_oct_m
#endif
  use profiling_oct_m
  use space_oct_m
  use types_oct_m
  use xc_cam_oct_m
 
  implicit none
  private
  public ::                     &
    fourier_space_op_t,         &
    dfourier_space_op_apply,    &
    zfourier_space_op_apply
 
  type fourier_space_op_t
    private
    real(real64),    allocatable :: dop(:, :, :)
    complex(real64), allocatable :: zop(:, :, :)
    type(accel_mem_t) :: op_buffer
    logical           :: real_op
    logical           :: in_device_memory = .false.
 
    !Parameters used to generate this kernel
    real(real64), allocatable, public :: qq(:)
    real(real64), public :: singularity = m_zero    
    real(real64), public :: mu = m_zero             
    real(real64), public :: alpha = m_zero          
    real(real64), public :: beta = m_zero           
 
  contains
    procedure :: init => fourier_space_op_init
    procedure :: dset_op => dfourier_space_op_set_op
    procedure :: zset_op => zfourier_space_op_set_op
    procedure :: end => fourier_space_op_end
  end type fourier_space_op_t
 
  real(real64), parameter, public :: VANISHING_Q = 1.0e-5_real64
  real(real64), parameter :: TOL_VANISHING_Q = 1e-6_real64
 
contains
 
  subroutine fourier_space_op_init(this, space, qvector, cam, singularity)
    class(fourier_space_op_t), intent(inout) :: this
    class(space_t),            intent(in)    :: space
    real(real64),              intent(in)    :: qvector(:)
    type(xc_cam_t),            intent(in)    :: cam
    real(real64),    optional, intent(in)    :: singularity
 
    push_sub(fourier_space_op_init)
 
    safe_allocate(this%qq(1:space%dim))
    this%qq(1:space%periodic_dim) = qvector(1:space%periodic_dim)
    this%qq(space%periodic_dim+1:space%dim) = vanishing_q
    ! Note, specific kernel builders will use this but return a different value
    ! or disregard entirely
    this%singularity = optional_default(singularity, m_zero)
    this%mu = cam%omega
    this%alpha = cam%alpha
    this%beta = cam%beta
 
    pop_sub(fourier_space_op_init)
 
  end subroutine fourier_space_op_init
 
  subroutine fourier_space_op_end(this)
    class(fourier_space_op_t), intent(inout) :: this
 
    push_sub(fourier_space_op_end)
 
    if (this%in_device_memory) then
      call accel_free_buffer(this%op_buffer)
      this%in_device_memory = .false.
    end if
    safe_deallocate_a(this%dop)
    safe_deallocate_a(this%zop)
    safe_deallocate_a(this%qq)
 
    pop_sub(fourier_space_op_end)
  end subroutine fourier_space_op_end
 
#include "undef.F90"
#include "real.F90"
#include "fourier_space_inc.F90"
 
#include "undef.F90"
#include "complex.F90"
#include "fourier_space_inc.F90"
 
end module fourier_space_oct_m
 
 
!! Local Variables:
!! mode: f90
!! coding: utf-8
!! End: