cube_function.F90

Go to the documentation of this file.

!! Copyright (C) 2002-2011 M. Marques, A. Castro, A. Rubio, G. Bertsch, M. Oliveira
!!
!! This program is free software; you can redistribute it and/or modify
!! it under the terms of the GNU General Public License as published by
!! the Free Software Foundation; either version 2, or (at your option)
!! any later version.
!!
!! This program is distributed in the hope that it will be useful,
!! but WITHOUT ANY WARRANTY; without even the implied warranty of
!! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!! GNU General Public License for more details.
!!
!! You should have received a copy of the GNU General Public License
!! along with this program; if not, write to the Free Software
!! Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
!! 02110-1301, USA.
!!
 
#include "global.h"
 
module cube_function_oct_m
  use accel_oct_m
  use cube_oct_m
  use debug_oct_m
  use fft_oct_m
  use global_oct_m
  use lalg_basic_oct_m
  use math_oct_m
  use mesh_oct_m
  use mesh_cube_map_oct_m
  use mesh_cube_parallel_map_oct_m
  use messages_oct_m
  use mpi_oct_m
  use mpi_debug_oct_m
  use partition_transfer_oct_m
  use par_vec_oct_m
  use profiling_oct_m
  use ring_pattern_oct_m
  use submesh_oct_m
  use types_oct_m
 
  implicit none
  private
  public ::                        &
    cube_function_t,               &
    cube_function_alloc_fs,        &
    cube_function_free_fs,         &
    cube_function_alloc_fs_single, &
    cube_function_free_fs_single,  &
    dcube_function_rs2fs,          &
    zcube_function_rs2fs,          &
    dcube_function_fs2rs,          &
    zcube_function_fs2rs,          &
    scube_function_rs2fs,          &
    ccube_function_rs2fs,          &
    scube_function_fs2rs,          &
    ccube_function_fs2rs,          &
    dcube_function_alloc_rs,       &
    zcube_function_alloc_rs,       &
    dcube_function_free_rs,        &
    zcube_function_free_rs,        &
    dcube_function_surface_average,&
    zcube_function_surface_average,&
    dmesh_to_cube_parallel,        &
    zmesh_to_cube_parallel,        &
    dcube_to_mesh_parallel,        &
    zcube_to_mesh_parallel,        &
    dmesh_to_cube,                 &
    zmesh_to_cube,                 &
    dcube_to_mesh,                 &
    zcube_to_mesh,                 &
    dsubmesh_to_cube,              &
    zsubmesh_to_cube,              &
    dcube_to_submesh,              &
    zcube_to_submesh,              &
    dcube_function_allgather,      &
    zcube_function_allgather,      &
    scube_function_alloc_rs,       &
    ccube_function_alloc_rs,       &
    scube_function_free_rs,        &
    ccube_function_free_rs,        &
    smesh_to_cube,                 &
    cmesh_to_cube,                 &
    scube_to_mesh,                 &
    ccube_to_mesh,                 &
    cube_map_is_trivial
 
  type cube_function_t
    ! Components are public by default
    integer :: batch_capacity = 1
    integer :: batch_size = 1
    real(real64),    pointer, contiguous :: dRS(:, :, :, :) => null() 
    complex(real64), pointer, contiguous :: zRS(:, :, :, :) => null() 
    complex(real64), pointer, contiguous :: FS(:, :, :, :)  => null() 
    real(real32),    pointer, contiguous :: sRS(:, :, :, :) => null() 
    complex(real32), pointer, contiguous :: cRS(:, :, :, :) => null() 
    complex(real32), pointer, contiguous :: cFS(:, :, :, :) => null() 
    logical            :: forced_alloc = .false. 
    logical            :: in_device_memory = .false.
    type(accel_mem_t) :: real_space_buffer
    type(accel_mem_t) :: fourier_space_buffer
  end type cube_function_t
 
  interface dmesh_to_cube
    module procedure dmesh_to_cube_1, dmesh_to_cube_2
  end interface dmesh_to_cube
 
  interface zmesh_to_cube
    module procedure zmesh_to_cube_1, zmesh_to_cube_2
  end interface zmesh_to_cube
 
  interface dcube_to_mesh
    module procedure dcube_to_mesh_1, dcube_to_mesh_2
  end interface dcube_to_mesh
 
  interface zcube_to_mesh
    module procedure zcube_to_mesh_1, zcube_to_mesh_2
  end interface zcube_to_mesh
 
  interface smesh_to_cube
    module procedure smesh_to_cube_1, smesh_to_cube_2
  end interface smesh_to_cube
 
  interface cmesh_to_cube
    module procedure cmesh_to_cube_1, cmesh_to_cube_2
  end interface cmesh_to_cube
 
  interface scube_to_mesh
    module procedure scube_to_mesh_1, scube_to_mesh_2
  end interface scube_to_mesh
 
  interface ccube_to_mesh
    module procedure ccube_to_mesh_1, ccube_to_mesh_2
  end interface ccube_to_mesh
 
contains
 
  subroutine cube_function_alloc_fs(cube, cf, force_alloc)
    type(cube_t), target,  intent(in)    :: cube
    type(cube_function_t), intent(inout) :: cf
    logical, optional,     intent(in)    :: force_alloc
 
    integer :: n1, n2, n3
    logical :: is_allocated
 
    push_sub(cube_function_alloc_fs)
 
    assert(.not. associated(cf%fs))
    assert(allocated(cube%fft))
 
    cf%forced_alloc = optional_default(force_alloc, .false.)
    ! cf has no init, so assign here; preserve cf%batch_size (active count) set by the caller
    cf%batch_capacity = cube%batch_capacity
 
    n1 = max(1, cube%fs_n(1))
    n2 = max(1, cube%fs_n(2))
    n3 = max(1, cube%fs_n(3))
 
    is_allocated = .false.
 
    select case (cube%fft%library)
    case (fftlib_pfft)
      if (.not. cf%forced_alloc) then
        is_allocated = .true.
        if (any(cube%fs_n(1:3) == 0)) then
          cf%fs => cube%fft%fs_data(1:1,1:1,1:1,1:cf%batch_capacity)
        else
          cf%fs => cube%fft%fs_data(1:n3,1:n1,1:n2,1:cf%batch_capacity)
        end if
      else ! force allocate transposed with PFFT
        is_allocated = .true.
        safe_allocate(cf%fs(1:n3, 1:n1, 1:n2, 1:cf%batch_capacity))
      end if
    case (fftlib_accel)
      if (cf%in_device_memory) then
        is_allocated = .true.
        call accel_create_buffer(cf%fourier_space_buffer, accel_mem_read_write, type_cmplx, &
          int(cf%batch_capacity, int64) * product(int(cube%fs_n(1:3), int64)))
      end if
 
    case (fftlib_fftw)
      if (.not. cf%forced_alloc) then
        is_allocated = .true.
        cf%fs => cube%fft%fs_data(1:cube%fs_n(1), 1:cube%fs_n(2), 1:cube%fs_n(3), 1:cf%batch_capacity)
      end if
    end select
 
    if (.not. is_allocated) then
      safe_allocate(cf%fs(1:cube%fs_n(1), 1:cube%fs_n(2), 1:cube%fs_n(3), 1:cf%batch_capacity))
    end if
 
    pop_sub(cube_function_alloc_fs)
  end subroutine cube_function_alloc_fs
 
 
  subroutine cube_function_free_fs(cube, cf)
    type(cube_t),          intent(in)    :: cube
    type(cube_function_t), intent(inout) :: cf
 
    logical :: deallocated
 
    push_sub(cube_function_free_fs)
 
    assert(allocated(cube%fft))
 
    deallocated = .false.
 
    select case (cube%fft%library)
    case (fftlib_pfft)
      if (.not. cf%forced_alloc) then
        deallocated = .true.
        nullify(cf%fs)
      end if
    case (fftlib_accel)
      if (cf%in_device_memory) then
        deallocated = .true.
        call accel_free_buffer(cf%fourier_space_buffer)
      end if
    case (fftlib_fftw)
      if (.not. cf%forced_alloc) then
        deallocated = .true.
        nullify(cf%fs)
      end if
    end select
 
    if (.not. deallocated) then
      assert(associated(cf%fs))
      safe_deallocate_p(cf%fs)
    end if
 
    pop_sub(cube_function_free_fs)
  end subroutine cube_function_free_fs
 
  ! ---------------------------------------------------------
  subroutine cube_function_alloc_fs_single(cube, cf)
    type(cube_t), target,  intent(in)    :: cube
    type(cube_function_t), intent(inout) :: cf
 
    push_sub(cube_function_alloc_fs_single)
 
    assert(.not. associated(cf%cFS))
    assert(allocated(cube%fft))
    assert(cube%fft%library == fftlib_fftw .or. cube%fft%library == fftlib_accel)
    assert(cube%fft%single)
 
    cf%batch_capacity = cube%batch_capacity
 
    if (cube%fft%library == fftlib_accel .and. cf%in_device_memory) then
      call accel_create_buffer(cf%fourier_space_buffer, accel_mem_read_write, type_cmplx_single, &
        int(cf%batch_capacity, int64) * product(int(cube%fs_n(1:3), int64)))
    else if (.not. cf%forced_alloc .and. cube%fft%aligned_memory) then
      cf%cFS => cube%fft%cfs_data(1:cube%fs_n(1), 1:cube%fs_n(2), 1:cube%fs_n(3), 1:cf%batch_capacity)
    else
      safe_allocate(cf%cFS(1:cube%fs_n(1), 1:cube%fs_n(2), 1:cube%fs_n(3), 1:cf%batch_capacity))
    end if
 
    pop_sub(cube_function_alloc_fs_single)
  end subroutine cube_function_alloc_fs_single
 
  ! ---------------------------------------------------------
  subroutine cube_function_free_fs_single(cube, cf)
    type(cube_t),          intent(in)    :: cube
    type(cube_function_t), intent(inout) :: cf
 
    push_sub(cube_function_free_fs_single)
 
    if (cube%fft%library == fftlib_accel .and. cf%in_device_memory) then
      call accel_free_buffer(cf%fourier_space_buffer)
    else if (.not. cf%forced_alloc .and. cube%fft%aligned_memory) then
      nullify(cf%cFS)
    else
      safe_deallocate_p(cf%cFS)
    end if
 
    pop_sub(cube_function_free_fs_single)
  end subroutine cube_function_free_fs_single
 
 
  ! ---------------------------------------------------------
  pure logical function cube_map_is_trivial(cube) result(trivial)
    type(cube_t), intent(in) :: cube
    trivial = cube%cube_map_present .and. allocated(cube%cube_map%map)
    if (.not. trivial) return
    ! is_trivial captures the mesh-side property; the additional checks
    ! verify the cube dimensions match the mesh and the cube origin aligns
    ! so that mesh point 1 lands at cube cell (1, 1, 1).
    trivial = cube%cube_map%is_trivial .and. &
      cube%cube_map%nmap == cube%rs_n(2) * cube%rs_n(3) .and. &
      cube%cube_map%map(mcm_count, 1) == cube%rs_n(1) .and. &
      cube%cube_map%map(1, 1) + cube%center(1) == 1 .and. &
      cube%cube_map%map(2, 1) + cube%center(2) == 1 .and. &
      cube%cube_map%map(3, 1) + cube%center(3) == 1
  end function cube_map_is_trivial
 
#include "undef.F90"
#include "real.F90"
#include "cube_function_inc.F90"
 
#include "undef.F90"
#include "complex.F90"
#include "cube_function_inc.F90"
 
#include "undef.F90"
#include "real32.F90"
#include "cube_function_inc.F90"
 
#include "undef.F90"
#include "complex32.F90"
#include "cube_function_inc.F90"
 
end module cube_function_oct_m
 
 
!! Local Variables:
!! mode: f90
!! coding: utf-8
!! End: