propagator_exp_mid_2step.F90

Go to the documentation of this file.

!! Copyright (C) 2020 Nicolas Tancogne-Dejean, Sebastian Ohlmann, Heiko Appel
!!
!! This program is free software; you can redistribute it and/or modify
!! it under the terms of the GNU General Public License as published by
!! the Free Software Foundation; either version 2, or (at your option)
!! any later version.
!!
!! This program is distributed in the hope that it will be useful,
!! but WITHOUT ANY WARRANTY; without even the implied warranty of
!! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!! GNU General Public License for more details.
!!
!! You should have received a copy of the GNU General Public License
!! along with this program; if not, write to the Free Software
!! Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
!! 02110-1301, USA.
!!
 
#include "global.h"
 
module propagator_exp_mid_2step_oct_m
  use, intrinsic :: iso_fortran_env
  use algorithm_oct_m
  use debug_oct_m
  use global_oct_m
  use propagator_oct_m
 
  implicit none
 
  private
  public ::                            &
    propagator_exp_mid_2step_t
 
 
  type, extends(propagator_t) :: propagator_exp_mid_2step_t
    private
  end type propagator_exp_mid_2step_t
 
  interface propagator_exp_mid_2step_t
    procedure propagator_exp_mid_2step_constructor
  end interface propagator_exp_mid_2step_t
 
  !# doc_start exp_mid_2step_propagation_operations
  ! Specific exponential mid-point propagation operations identifiers
  character(len=ALGO_LABEL_LEN), public, parameter :: &
    EXPMID_2STEP_START        = 'EXPMID_2STEP_START',             &
    expmid_2step_finish       = 'EXPMID_2STEP_FINISH',            &
    expmid_2step_predict_dt_2 = 'EXPMID_2STEP_PREDICT_DT_2',      &
    expmid_2step_predict_dt   = 'EXPMID_2STEP_PREDICT_DT',        &
    expmid_2step_correct_dt_2 = 'EXPMID_2STEP_CORRECT_DT_2',      &
    update_hamiltonian  = 'UPDATE_HAMILTONIAN'
 
  ! Specific exponential mid-point propagation operations
  type(algorithmic_operation_t), public, parameter :: &
    OP_EXPMID_2STEP_START        = algorithmic_operation_t(expmid_2step_start,        &
    'Starting exponential mid-point propagation'),  &
    op_expmid_2step_finish       = algorithmic_operation_t(expmid_2step_finish,       &
    'Finishing exponential mid-point propagation'), &
    op_expmid_2step_predict_dt_2 = algorithmic_operation_t(expmid_2step_predict_dt_2, &
    'Prediction step - Predicting state at dt/2 '), &
    op_expmid_2step_predict_dt   = algorithmic_operation_t(expmid_2step_predict_dt,   &
    'Prediction step - Predicting state at dt'),    &
    op_expmid_2step_correct_dt_2 = algorithmic_operation_t(expmid_2step_correct_dt_2, &
    'Correction step - Correcting state at dt/2'),  &
    op_update_hamiltonian  = algorithmic_operation_t(update_hamiltonian,  'Updating Hamiltonian')
  !# doc_end
 
contains
 
  ! ---------------------------------------------------------
  function propagator_exp_mid_2step_constructor(dt, predictor_corrector) result(this)
    float,                     intent(in) :: dt
    logical,                   intent(in) :: predictor_corrector
    type(propagator_exp_mid_2step_t), pointer   :: this
 
    push_sub(propagator_exp_mid_2step_constructor)
 
    allocate(this)
 
    this%predictor_corrector = predictor_corrector
    this%start_operation = op_expmid_2step_start
    this%final_operation = op_expmid_2step_finish
 
    if (predictor_corrector) then
 
      call this%add_operation(op_store_current_status)
      call this%add_operation(op_expmid_2step_predict_dt_2)  ! predict: psi(t+dt/2) = 0.5*(U_H(dt) psi(t) + psi(t)) or via extrapolation
      call this%add_operation(op_update_couplings)
      call this%add_operation(op_start_scf_loop)
      call this%add_operation(op_update_interactions)
      call this%add_operation(op_update_hamiltonian)         ! update: H(t+dt/2) from psi(t+dt/2)
      call this%add_operation(op_expmid_2step_predict_dt)    ! predict: psi(t+dt) = U_H(t+dt/2) psi(t)
      call this%add_operation(op_expmid_2step_correct_dt_2)  ! correct: psi(t+dt/2) = 0.5*(psi(t+dt) + psi(t))
      call this%add_operation(op_end_scf_loop)
      call this%add_operation(op_iteration_done)
      call this%add_operation(op_rewind_algorithm)
 
      this%max_scf_count = 10
      this%scf_tol = 1e-6_real64 ! At the moment arbitrary. This is system specific and should be adapted.
 
    else
 
      call this%add_operation(op_store_current_status)
      call this%add_operation(op_expmid_2step_predict_dt_2)  ! predict: psi(t+dt/2) = 0.5*(U_H(dt) psi(t) + psi(t)) or via extrapolation
      call this%add_operation(op_update_couplings)
      call this%add_operation(op_update_interactions)
      call this%add_operation(op_update_hamiltonian)         ! update: H(t+dt/2) from psi(t+dt/2)
      call this%add_operation(op_expmid_2step_predict_dt)    ! predict: psi(t+dt) = U_H(t+dt/2) psi(t)
      call this%add_operation(op_update_couplings)
      call this%add_operation(op_update_interactions)
      call this%add_operation(op_update_hamiltonian)         ! update: H(t+dt) from psi(t+dt)
      call this%add_operation(op_iteration_done)
      call this%add_operation(op_rewind_algorithm)
 
    end if
 
    ! The implicit exponential midpoint has two algorithmic steps
    this%algo_steps = 2
 
    this%dt = dt
 
    pop_sub(propagator_exp_mid_2step_constructor)
  end function propagator_exp_mid_2step_constructor
 
end module propagator_exp_mid_2step_oct_m
 
 
!! Local Variables:
!! mode: f90
!! coding: utf-8
!! End: