coulomb_force.F90

Go to the documentation of this file.

!! Copyright (C) 2020 Heiko Appel
!!
!! This program is free software; you can redistribute it and/or modify
!! it under the terms of the GNU General Public License as published by
!! the Free Software Foundation; either version 2, or (at your option)
!! any later version.
!!
!! This program is distributed in the hope that it will be useful,
!! but WITHOUT ANY WARRANTY; without even the implied warranty of
!! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!! GNU General Public License for more details.
!!
!! You should have received a copy of the GNU General Public License
!! along with this program; if not, write to the Free Software
!! Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
!! 02110-1301, USA.
!!
 
#include "global.h"
 
module coulomb_force_oct_m
  use debug_oct_m
  use force_interaction_oct_m
  use global_oct_m
  use interaction_oct_m
  use interaction_partner_oct_m
  use messages_oct_m
  use namespace_oct_m
  use profiling_oct_m
  use quantity_oct_m
 
  implicit none
 
  private
  public ::                &
    coulomb_force_t
 
  type, extends(force_interaction_t) :: coulomb_force_t
    private
    real(real64), pointer :: system_charge(:) => null() 
    real(real64), pointer :: system_pos(:,:)  => null()  
 
    integer, public :: partner_np = 0
    real(real64), allocatable, public :: partner_charge(:)
    real(real64), allocatable, public :: partner_pos(:,:)
 
  contains
    procedure :: init => coulomb_force_init
    procedure :: calculate => coulomb_force_calculate
    procedure :: calculate_energy => coulomb_force_calculate_energy
    final :: coulomb_force_finalize
  end type coulomb_force_t
 
  interface coulomb_force_t
    module procedure coulomb_force_constructor
  end interface coulomb_force_t
 
contains
 
  ! ---------------------------------------------------------
  function coulomb_force_constructor(partner) result(this)
    class(interaction_partner_t), target, intent(inout) :: partner
    class(coulomb_force_t),               pointer       :: this
 
    push_sub(coulomb_force_constructor)
 
    allocate(this)
 
    this%label = "coulomb_force"
 
    this%partner => partner
 
    ! The Coulomb force needs the position and charge of the system
    this%system_quantities = [position, charge]
 
    ! The Coulomb force needs the position and charge of the partner
    this%couplings_from_partner = [position, charge]
 
    pop_sub(coulomb_force_constructor)
  end function coulomb_force_constructor
 
  ! ---------------------------------------------------------
  subroutine coulomb_force_init(this, dim, system_np, system_charge, system_pos)
    class(coulomb_force_t),             intent(inout) :: this
    integer,                            intent(in)    :: dim
    integer,                            intent(in)    :: system_np
    real(real64),               target, intent(in)    :: system_charge(:)
    real(real64),               target, intent(in)    :: system_pos(:,:)
 
    push_sub(coulomb_force_init)
 
    this%dim = dim
    this%system_np = system_np
    safe_allocate(this%force(1:dim, 1:system_np))
    this%force = m_zero
 
    this%system_charge => system_charge
    this%system_pos => system_pos
 
    pop_sub(coulomb_force_init)
  end subroutine coulomb_force_init
 
  ! ---------------------------------------------------------
  subroutine coulomb_force_calculate(this)
    class(coulomb_force_t),             intent(inout) :: this
 
    integer :: ip, jp
    real(real64), parameter :: COULCONST = m_one ! Coulomb constant in atomic units
    real(real64) :: dist3
 
    push_sub(coulomb_force_calculate)
 
    assert(allocated(this%partner_charge))
    assert(allocated(this%partner_pos))
 
    do ip = 1, this%system_np
      do jp = 1, this%partner_np
        if (this%intra_interaction .and. ip == jp ) cycle
 
        dist3 = sum((this%partner_pos(1:this%dim, jp) - this%system_pos(1:this%dim, ip))**2)**(m_three/m_two)
 
        this%force(1:this%dim, ip) = -(this%partner_pos(1:this%dim, jp) - this%system_pos(1:this%dim, ip)) &
          / (dist3 + m_epsilon) * (coulconst * this%system_charge(ip) * this%partner_charge(jp))
      end do
    end do
 
    pop_sub(coulomb_force_calculate)
  end subroutine coulomb_force_calculate
 
  ! ---------------------------------------------------------
  subroutine coulomb_force_calculate_energy(this)
    class(coulomb_force_t),             intent(inout) :: this
 
    integer :: ip, jp
    real(real64), parameter :: coulconst = m_one ! Coulomb constant in atomic units
    real(real64) :: dist
 
    push_sub(coulomb_force_calculate_energy)
 
    assert(allocated(this%partner_charge))
    assert(allocated(this%partner_pos))
 
    this%energy = m_zero
    do ip = 1, this%system_np
      do jp = 1, this%partner_np
        if (this%intra_interaction .and. ip == jp ) cycle
 
        dist = sqrt(sum((this%partner_pos(1:this%dim, jp) - this%system_pos(1:this%dim, ip))**2))
 
        this%energy = this%energy + m_half  / (dist + m_epsilon) * (coulconst * this%system_charge(ip) * this%partner_charge(jp))
      end do
    end do
 
    pop_sub(coulomb_force_calculate_energy)
  end subroutine coulomb_force_calculate_energy
 
 
  ! ---------------------------------------------------------
  subroutine coulomb_force_finalize(this)
    type(coulomb_force_t), intent(inout) :: this
 
    push_sub(coulomb_force_finalize)
 
    this%force = m_zero
    nullify(this%system_charge)
    nullify(this%system_pos)
    safe_deallocate_a(this%partner_pos)
    safe_deallocate_a(this%partner_charge)
    safe_deallocate_a(this%force)
 
    call interaction_end(this)
 
    pop_sub(coulomb_force_finalize)
  end subroutine coulomb_force_finalize
 
end module coulomb_force_oct_m
 
!! Local Variables:
!! mode: f90
!! coding: utf-8
!! End: