box_user_defined.F90

Go to the documentation of this file.

!! Copyright (C) 2002-2006 M. Marques, A. Castro, A. Rubio, G. Bertsch
!! Copyright (C) 2021 M. Oliveira, K. Lively, A. Obzhirov, I. Albar
!!
!! This program is free software; you can redistribute it and/or modify
!! it under the terms of the GNU General Public License as published by
!! the Free Software Foundation; either version 2, or (at your option)
!! any later version.
!!
!! This program is distributed in the hope that it will be useful,
!! but WITHOUT ANY WARRANTY; without even the implied warranty of
!! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!! GNU General Public License for more details.
!!
!! You should have received a copy of the GNU General Public License
!! along with this program; if not, write to the Free Software
!! Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
!! 02110-1301, USA.
!!
 
#include "global.h"
 
module box_user_defined_oct_m
  use box_oct_m
  use box_parallelepiped_oct_m
  use box_shape_oct_m
  use debug_oct_m
  use global_oct_m
  use messages_oct_m
  use namespace_oct_m
  use parser_oct_m
  use profiling_oct_m
  use string_oct_m
  use unit_oct_m
 
  implicit none
 
  private
  public :: box_user_defined_t
 
  type, extends(box_shape_t) :: box_user_defined_t
    private
    type(box_parallelepiped_t), pointer :: outer_box
    character(len=1024)                 :: expression
  contains
    procedure :: shape_contains_points => box_user_defined_shape_contains_points
    procedure :: write_info => box_user_defined_write_info
    procedure :: short_info => box_user_defined_short_info
    final     :: box_user_defined_finalize
  end type box_user_defined_t
 
  interface box_user_defined_t
    procedure box_user_defined_constructor
  end interface box_user_defined_t
 
contains
 
  !--------------------------------------------------------------
  function box_user_defined_constructor(dim, center, axes, expression, length, namespace) result(box)
    integer,             intent(in) :: dim
    real(real64),        intent(in) :: center(dim)
    real(real64),        intent(in) :: axes(dim, dim)
    character(len=1024), intent(in) :: expression
    real(real64),        intent(in) :: length(dim)
    type(namespace_t),   intent(in) :: namespace
    class(box_user_defined_t), pointer :: box
 
    push_sub(box_user_defined_constructor)
 
    ! Allocate memory
    safe_allocate(box)
 
    ! Initialize box
    call box_shape_init(box, namespace, dim, center, bounding_box_min=-m_half*length, bounding_box_max=m_half*length, axes=axes)
    box%expression = expression
    call conv_to_c_string(box%expression)
    box%outer_box => box_parallelepiped_t(dim, center, axes, length, namespace)
 
    box%bounding_box_l = m_half*length + abs(center)
 
    pop_sub(box_user_defined_constructor)
  end function box_user_defined_constructor
 
  !--------------------------------------------------------------
  subroutine box_user_defined_finalize(this)
    type(box_user_defined_t), intent(inout) :: this
 
    push_sub(box_user_defined_finalize)
 
    call box_shape_end(this)
    safe_deallocate_p(this%outer_box)
 
    pop_sub(box_user_defined_finalize)
  end subroutine box_user_defined_finalize
 
  !--------------------------------------------------------------
  function box_user_defined_shape_contains_points(this, nn, xx) result(contained)
    class(box_user_defined_t), intent(in)  :: this
    integer,                   intent(in)  :: nn
    real(real64), contiguous,         intent(in)  :: xx(:,:)
    logical :: contained(1:nn)
 
    integer :: ip
    real(real64) :: re, im, rr, xx_centered(this%dim)
 
    contained = this%outer_box%contains_points(nn, xx)
 
    do ip = 1, nn
      if (.not. contained(ip)) then
        ! Skip points that are outside the outer box
        cycle
      end if
 
      xx_centered = xx(ip, :) - this%center
      rr = norm2(xx_centered)
      call parse_expression(re, im, this%dim, xx_centered, rr, m_zero, this%expression)
      contained(ip) = abs(re) > m_epsilon .neqv. this%is_inside_out()
    end do
 
  end function box_user_defined_shape_contains_points
 
  !--------------------------------------------------------------
  subroutine box_user_defined_write_info(this, iunit, namespace)
    class(box_user_defined_t),   intent(in) :: this
    integer,           optional, intent(in) :: iunit
    type(namespace_t), optional, intent(in) :: namespace
 
    push_sub(box_user_defined_write_info)
 
    write(message(1),'(2x,a)') 'Type = user-defined'
    call messages_info(1, iunit=iunit, namespace=namespace)
 
    pop_sub(box_user_defined_write_info)
  end subroutine box_user_defined_write_info
 
  !--------------------------------------------------------------
  character(len=BOX_INFO_LEN) function box_user_defined_short_info(this, unit_length) result(info)
    class(box_user_defined_t), intent(in) :: this
    type(unit_t),              intent(in) :: unit_length
 
    push_sub(box_user_defined_short_info)
 
    write(info,'(3a)') 'BoxShape = user_defined; BoxShapeUsDef = "', trim(this%expression), '"'
 
    pop_sub(box_user_defined_short_info)
  end function box_user_defined_short_info
 
end module box_user_defined_oct_m
 
!! Local Variables:
!! mode: f90
!! coding: utf-8
!! End: